Bidang MySQL yang diindeks tidak menyimpan nilai saat membuat/mengedit catatan melalui ADO

Saya dapat membuat ulang masalah Anda dengan versi 64-bit dari MySQL ODBC 5.3 Unicode Driver (5.03.04.00). Tampaknya ada masalah dengan pembaruan ADO Recordset ketika kolom terakhir dalam tabel bertipe TEXT . Saya bahkan tidak memiliki indeks di userid dan saya mendapatkan hasil yang sama.

Salah satu solusi yang mungkin adalah menggunakan ADODB.Command dengan parameter untuk melakukan penyisipan menggunakan kode yang mirip dengan ini:

Dim oConn As ADODB.Connection
Dim cmd As ADODB.Command

Set oConn = New ADODB.Connection
oConn.Open _
        "Driver=MySQL ODBC 5.3 Unicode Driver;" & _
        "SERVER=localhost;" & _
        "UID=root;" & _
        "PWD=whatever;" & _
        "DATABASE=mydb;" & _
        "PORT=3306;" & _
        "DFLT_BIGINT_BIND_STR=1"

Set cmd = New ADODB.Command
cmd.ActiveConnection = oConn
cmd.CommandText = _
        "INSERT INTO phplist_user_user_history " & _
        "(`userid`, `ip`, `date`, `Summary`, `Detail`, `systeminfo`) " & _
        "VALUES (?,?,?,?,?,?)"
cmd.Parameters.Append cmd.CreateParameter("?", adInteger, adParamInput, , 456)
cmd.Parameters.Append cmd.CreateParameter("?", adVarWChar, adParamInput, 255, "")
cmd.Parameters.Append cmd.CreateParameter("?", adDBTimeStamp, adParamInput, 255, Now)
cmd.Parameters.Append cmd.CreateParameter("?", adVarWChar, adParamInput, 255, "cHistory.Subject")
cmd.Parameters.Append cmd.CreateParameter("?", adLongVarWChar, adParamInput, 2147483647, "cHistory.Body")
cmd.Parameters.Append cmd.CreateParameter("?", adLongVarWChar, adParamInput, 2147483647, "Automated syncronization process.")
cmd.Execute

Set cmd = Nothing
oConn.Close
Set oConn = Nothing

Saya mengujinya dari database Access 2010 dan berfungsi dengan baik untuk saya.