Memanipulasi koleksi

Setidaknya Anda kehilangan definisi tabel dalam kasus kedua. Pernyataan ini:

create or replace TYPE tbl_list2 IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));

hanya mendeklarasikan tipe objek (atau record), bukan tabel.

Jadi, Anda perlu melakukannya dalam 2 langkah:

create or replace TYPE tbl_list_rec IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));
/

create or replace TYPE tbl_list2 as table of tbl_list_rec;
/

Setelah itu Anda memerlukan beberapa koreksi sintaks dalam skrip:

declare
  l_object tbl_list2;
  i        number;
begin
  -- for list initialization it must be filled with constructed objects
  l_object := tbl_list2( tbl_list_rec('','') );

  for i in 1..100000 loop          

    -- 1. select values to variable
    -- 2. Fix constructor for list 
    select 
      l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
    into 
      l_object 
    from 
      dual;

    end loop;

    for i in l_object.first ..  l_object.last loop
      -- output separate fields, there are now default conversion from 
      -- user-defined objects to varchar2.
      dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
    end loop;  

end;
/

PERBARUI

Solusi di atas relatif lambat karena sejumlah besar sakelar konteks. Tetapi perbandingan instance tipe objek yang kompleks tidak dapat dilakukan secara langsung di PL/SQL tanpa beberapa pekerjaan tambahan.
Untuk memungkinkan Oracle mengetahui apakah instance objek sama atau berbeda, kita perlu mendefinisikan metode pemetaan atau pengurutan untuk jenis objek . Kedua jenis metode tersebut tidak diperbolehkan, sehingga harus dipilih yang tepat. Metode MAP bekerja lebih cepat dan tidak perlu memesan dalam kasus kami, jadi lakukanlah:

create or replace TYPE tbl_list_rec2 AS OBJECT (
  l_owner  VARCHAR2(64),
  l_name  VARCHAR2(64),
  map member function get_key return varchar2
);
/

Implementasi:

create or replace TYPE BODY tbl_list_rec2 AS 

  map member function get_key return varchar2
  is
  begin
    return l_owner||chr(1)||l_name;
  end;

end;
/

Setelah itu dimungkinkan untuk menguji objek untuk kesetaraan dalam kode PL/SQL seperti varchar2 sederhana dalam contoh pertama dari pertanyaan:

declare
  l_object tbl_list2a;
  i        number; 
begin
  l_object := tbl_list2a( tbl_list_rec2('','') );

  for i in 1..100000 loop          
    l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
  end loop;

  for i in l_object.first..  l_object.last loop
    dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
  end loop;  

end;
/