Oracle:Apakah ada cara untuk mendapatkan kesalahan sintaks SQL terbaru?

Anda dapat membuat pemicu di Oracle yang akan mencatat semua kesalahan (atau hampir semua - NO_DATA_FOUND tidak dianggap sebagai kesalahan). Dalam contoh di bawah ini, setiap kesalahan dalam skema dicatat dalam tabel TRACK_DETAIL (kesalahan dalam satu baris, SQL gagal di baris berikutnya). Anda dapat membuatnya lebih canggih dengan nomor urut, tanggal/waktu dll.

create table track_detail (val varchar2(4000));

create or replace procedure track (p_text IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION;
begin
  insert into track_detail(val)
  values (p_text);
  commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
  v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
  v_num NUMBER;
  v_sql_text ora_name_list_t;
begin
  v_temp := translate(v_temp,'''','"');
  track(v_temp);
  v_num  := ora_sql_txt(v_sql_text);
  v_temp := null;
  BEGIN
    FOR i IN 1..v_num LOOP
      v_temp := v_temp || v_sql_text(i);
    END LOOP;
  EXCEPTION
    WHEN VALUE_ERROR THEN NULL;
  END;
  v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
  track(v_temp);
end;
/

Ingatlah untuk menjatuhkan (atau menonaktifkan) pemicu setelah Anda selesai menggunakannya.