Menyimpan kata sandi dengan Node.js dan MongoDB

Gunakan ini:https://github.com/ncb000gt/node.bcrypt.js/

bcrypt adalah salah satu dari sedikit algoritma yang berfokus pada kasus penggunaan ini. Anda seharusnya tidak pernah dapat mendekripsi sandi Anda, hanya verifikasi bahwa sandi teks-jelas yang dimasukkan pengguna cocok dengan hash yang disimpan/dienkripsi.

bcrypt sangat mudah digunakan. Berikut ini cuplikan dari skema Pengguna Mongoose saya (dalam CoffeeScript). Pastikan untuk menggunakan fungsi async karena bycrypt lambat (disengaja).

class User extends SharedUser
  defaults: _.extend {domainId: null}, SharedUser::defaults

  #Irrelevant bits trimmed...

  password: (cleartext, confirm, callback) ->
    errorInfo = new errors.InvalidData()
    if cleartext != confirm
      errorInfo.message = 'please type the same password twice'
      errorInfo.errors.confirmPassword = 'must match the password'
      return callback errorInfo
    message = min4 cleartext
    if message
      errorInfo.message = message
      errorInfo.errors.password = message
      return callback errorInfo
    self = this
    bcrypt.gen_salt 10, (error, salt)->
      if error
        errorInfo = new errors.InternalError error.message
        return callback errorInfo
      bcrypt.encrypt cleartext, salt, (error, hash)->
        if error
          errorInfo = new errors.InternalError error.message
          return callback errorInfo
        self.attributes.bcryptedPassword = hash
        return callback()

  verifyPassword: (cleartext, callback) ->
    bcrypt.compare cleartext, @attributes.bcryptedPassword, (error, result)->
      if error
        return callback(new errors.InternalError(error.message))
      callback null, result

Baca juga artikel ini, yang akan meyakinkan Anda bahwa bcrypt adalah pilihan yang baik dan membantu Anda menghindari menjadi "baik dan benar-benar berhasil".